Manage Projects with Terraform

• Part 1: Manage Environments with Terraform - Set up environments with policies
• Part 2: Manage Databases with Terraform - Register database instances
• Part 3: Manage Projects with Terraform 👈
• Part 4: Manage Bytebase Settings with Terraform - Configure workspace profile and approval policies
• Part 5: Manage SQL Review Rules with Terraform - Define SQL review policies
• Part 6: Manage Users and Groups with Terraform - Configure users and groups
• Part 7: Manage Database Access Control with Terraform - Grant database permissions
• Part 8: Manage Data Masking with Terraform - Protect sensitive data

​

What You’ll Learn

• Organize databases into logical project groups for better management
• Configure project-specific settings and policies
• Set up webhooks for project notifications
• Choose between dynamic and explicit database assignment patterns

​

Prerequisites

• Completed Part 1: Manage Environments with Terraform and Part 2: Manage Databases with Terraform
• Access to the built-in Test Sample Instance and Prod Sample Instance from Bytebase sample data
• Your Terraform workspace from the previous tutorials

​

Step 1 - Understand Current Setup

• Test instance: Contains hr_test and postgres databases
• Prod instance: Contains hr_prod and postgres databases

​

Step 2 - Create Projects

# Project One - Development/Test Environment
# Uses dynamic assignment to automatically include all test databases
resource "bytebase_project" "project-one" {
  depends_on  = [bytebase_instance.test]
  resource_id = "project-one"
  title       = "Project One"

  # Project-level governance
  enforce_sql_review          = true
  require_issue_approval      = true
  require_plan_check_no_error = true
  allow_request_role          = true
  allow_just_in_time_access   = true
  force_issue_labels          = false

  # Issue labels available in this project
  issue_labels {
    value = "schema-change"
    color {
      red   = 0
      green = 0.4
      blue  = 0.8
    }
    group = "type"
  }
  issue_labels {
    value = "data-change"
    color {
      red   = 0.8
      green = 0.4
      blue  = 0
    }
    group = "type"
  }

  # Project-level labels
  labels = {
    environment = "test"
    team        = "platform"
  }

  # Dynamically include all databases from the test instance
  databases = bytebase_instance.test.databases

  # Configure Slack notifications for team collaboration
  webhooks {
    title = "Sample webhook 1"
    type  = "SLACK"
    url   = "https://webhook.site/91fcd52a-39f1-4e7b-a43a-ddf72796d6b1"
    notification_types = [
      "ISSUE_CREATED",
      "ISSUE_APPROVAL_REQUESTED",
      "PIPELINE_COMPLETED",
    ]
  }
}

# Project Two - Production Environment
# Uses explicit assignment for precise control over production databases
resource "bytebase_project" "project-two" {
  depends_on  = [bytebase_instance.prod]
  resource_id = "project-two"
  title       = "Project Two"

  # Explicitly specify which production databases to include
  databases = [
    "instances/prod-sample-instance/databases/hr_prod"
  ]
}

​

Database Assignment Patterns

​

Dynamic Assignment

databases = bytebase_instance.test.databases

• Automatically includes all databases from a specified instance
• Best for: Development and testing environments where databases change frequently
• Benefit: Self-maintaining as new databases are automatically included

​

Explicit Assignment

databases = ["instances/prod-sample-instance/databases/hr_prod"]

• Manually specify each database by its full path
• Best for: Production environments requiring precise control
• Benefit: Granular control over which databases belong to the project

​

Step 3 - Apply Configuration

terraform plan
terraform apply

​

Step 4 - Verify Projects

1. Navigate to Projects in the Bytebase GUI.
2. You should now see three projects organized as follows:
   • Sample Project (original default project, now empty after database migration)
   • Project One (contains both hr_test and postgres databases from Test Sample Instance)
   • Project Two (contains the hr_prod database from Prod Sample Instance)
3. Click on Project One and navigate to Settings to review the configurations you’ve applied.
4. Click Webhooks and you’ll see the webhook you set.

​

Summary and Next Steps

• Project Organization: Projects serve as logical containers that group related databases for improved management and governance
• Assignment Flexibility: Choose between dynamic assignment (automatic inclusion) for development environments or explicit assignment (manual control) for production
• Cross-Environment Projects: Projects can span multiple environments, though it’s often better to separate test and production databases into different projects
• Project Configuration: Customize project behavior with settings like SQL review enforcement, issue approval requirements, and access controls
• Notification Integration: Set up webhooks to keep your team informed about project activities through Slack or other channels